VBA Word

Word is a Microsoft application used for word processing. VBA is embdedded within the Word application and can be used to programmatically work with Word. The Word Object Library contains classes that make working with Word in VBA possible. The classes in the Word Object Library are collectively referred to as the Word Object Model. When using VBA in Word, a reference is included to the Word Object Library.

Word Object Model

The Word Object Model contains classes that make it possible to work with Word in VBA. The Word Object Model contains many classes but the general overview of the model is Application → Document → Range.

1. Application
   1. Documents
      1. Document
         1. Range
         2. Sentences
         3. Paragraphs
            1. Paragraph
         4. Bookmarks
            1. Bookmark
         5. Tables
            1. Table
         6. ContentControls
            1. ContentControl
         7. Comments
            1. Comment
         8. MailMerge
   2. Windows
      1. Window
   3. Selection

Context

The place where VBA code is written determines the implied context when referring to classes. For example, when using VBA in Word and referring to the Application object, it is implied that Application and Word.Application are the same object. However, when using VBA in another application to work with Word, it is necessary to qualify references to avoid naming collisions with classes in the other application. Using qualified references requires that a reference is set to the library where the classes are defined. If a reference cannot be set, late-binding can be used instead.

Public Sub Example()

    '''In Word

    Debug.Print Application Is Word.Application 'Prints: True

End Sub

Public Sub Example()

    '''In Excel

    'Requires a reference to the Word Object Library

    Debug.Print Application Is Word.Application 'Prints: False

    Debug.Print Application Is Excel.Application 'Prints: True

End Sub

To retrieve the Word Application object from another application, attempt to retrieve the running application and if that fails start a new instance of the application.

Public Function GetWordApp() As Object

    On Error Resume Next
    Set GetWordApp = GetObject(, "Word.Application")
    On Error GoTo 0

    If GetWordApp Is Nothing Then
        Set GetWordApp = CreateObject("Word.Application")
    End If

End Sub

Application

The Application object represents the Word application itself. The Application object is the top-level object and provides access to the rest of the Word Object Model. The Application object can be used to access functionality and properties of the Word application.

Public Sub Example()

    Word.Application.Options.DisplayGridLines = True

End Sub

Public Sub Example()

    Debug.Print Word.Application.CheckGrammar("Hello my name is Peter.")
    Debug.Print Word.Application.CheckGrammar("Hello, my name is Peter.")

    Debug.Print Word.Application.CheckSpelling("Helllo, how are you?")
    Debug.Print Word.Application.CheckSpelling("Hello, how are you?")

    Dim S As String
    S = "Hello," & Chr(0) & "World!"
    S = Word.Application.CleanString(S)
    Debug.Print Asc(Mid$(S, 7, 1)) 'Null character replaced with Space

End Sub

Documents

The Document class represents a Word document. The Documents collection object represents all open Word documents and can be accessed from the Application.Documents property.

Public Sub Example()

    Dim D As Word.Document

    For Each D In Word.Application.Documents
        Debug.Print D.Name
    Next D

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents.Add 

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents.Add

    D.SaveAs2 Environ$("USERPROFILE") & "\Desktop\Example.docx", wdFormatDocumentDefault

    D.Content.InsertAfter "Hello, World!"

    D.Save

End Sub

Public Sub Example()

    Dim D As Word.Document

    Set D = Word.Application.Documents.Open(Environ$("USERPROFILE") & "\Desktop\Example.docx")

    D.Content.InsertAfter "Hello, World!"

    D.Save

    D.Close

End Sub

Public Sub Example()
    
    Dim D As Word.Document
    Set D = Word.Application.Documents(1)
    
    D.CheckSpelling
    D.CheckGrammar
    
End Sub

Ranges

The Range object represents an area of a Word document. Working with Ranges is important for using VBA with Word. There are different ways to retrieve a Range object.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Word.Range
    Set R = D.Range(0, 10)

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Word.Range
    Set R = D.Paragraphs(1).Range

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Word.Range
    Set R = D.Content

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Word.Range
    Set R = D.StoryRanges(wdMainTextStory) 'Same as Document.Content

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = ThisDocument

    Dim Ss As Word.Sentences
    Set Ss = D.Range.Sentences

    Dim S As Word.Range
    For Each S In Ss
        Debug.Print S.Text
    Next S

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Range
    Set R = D.Paragraphs(1).Range

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim R As Word.Range
    For Each R In D.Words
        Debug.Print R.Text
    Next R

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    D.Content.CheckSpelling
    D.Content.CheckGrammar
    D.Content.Words(1).CheckSynonyms

End Sub

Paragraphs

The Paragraph object represents a paragraph. The Paragraphs collection object contains a collection of Paragraph objects. Use the Document.Paragraphs property or the Range.Paragraphs property to get a Paragraphs collection containing all paragraphs in a Document or Range. The Paragraph object and the Paragraphs collection object have many of the same properties and methods. It may not be necessary to loop over all Paragraph objects in the collection, but instead call a particular method on the entire collection.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    D.Paragraphs.IndentFirstLineCharWidth 4

End Sub

Bookmarks

The Bookmark class represents a Bookmark. The Bookmarks collection object contains a collection of Bookmark objects. Use the Document.Bookmarks property to get a Bookmarks collection containing all Bookmarks in a Document. Bookmarks can be used to locate part of a document.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim B As Word.Bookmark
    Set B = D.Bookmarks.Add("Test", D.Range(0, 0))

End Sub

Tables

The Table object represents a table with rows and columns. The Tables collection object contains a collection of Table objects. Use the Document.Tables property to get a Tables collection containing all Table objects in a Document.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim T As Word.Table
    Set T = D.Tables.Add(D.Range(0, 0), 10, 3)

    With T.Borders
        .OutsideLineStyle = wdLineStyleSingle
        .OutsideLineWidth = wdLineWidth025pt
        .InsideLineStyle = wdLineStyleSingle
    End With

    T.Cell(1, 1).Range.Text = "Header1"
    T.Cell(1, 2).Range.Text = "Header2"
    T.Cell(1, 3).Range.Text = "Header3"

    T.Rows(1).Range.Bold = True

    T.Range.ParagraphFormat.Alignment = wdAlignParagraphCenter
    T.Rows(1).Cells.VerticalAlignment = wdCellAlignVerticalCenter

End Sub

ContentControls

The ContentControl object represents a control. The ContentControls collection object contains ContentControl objects. Use the Document.ContentControls property to get a ContentControls collection containing all ContentControl objects in a Document.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim CC As Word.ContentControl
    Set CC = D.ContentControls.Add(wdContentControlDropdownList, D.Range(0, 0))

    CC.DropdownListEntries.Add "List Entry 1", "Value 1", 1
    CC.DropdownListEntries.Add "List Entry 2", "Value 2", 2
    CC.DropdownListEntries.Add "List Entry 3", "Value 3", 3

End Sub

Comments

The Comment object represents a comment. The Comments collection object contains a collection of Comment objects. Use the Document.Comments property to get a Comments collection containing all Comment objects in a Document.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim C As Word.Comment
    Set C = D.Comments.Add(D.Range(0, 0), "Test Comment")

End Sub

MailMerge

The MailMerge object provides the ability to use the MailMerge feature in VBA.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim SourcePath As String
    SourcePath = "C:\ExampleMailingList.xlsx"

    D.MailMerge.Fields.Add Range:=D.Range(0, 0), Name:="Name"
    D.MailMerge.OpenDataSource _
        Name:=SourcePath, _
        ConfirmConversions:=False, _
        ReadOnly:=False, _
        LinkToSource:=True, _
        AddToRecentFiles:=False, _
        PasswordDocument:="", _
        PasswordTemplate:="", _
        WritePasswordDocument:="", _
        WritePasswordTemplate:="", _
        Revert:=False, _
        Format:=wdOpenFormatAuto, _
        Connection:= _
            "Provider=Microsoft.ACE.OLEDB.12.0;" & _
            "User ID=Admin;" & _
            "Data Source=" & SourcePath & ";" & _
            "Mode=Read;" & _
            "Extended Properties=""HDR=YES;IMEX=1;"";" & _
            "Jet OLEDB:System database="""";" & _
            "Jet OLEDB:Registry Path="""";" & _
            "Jet OLEDB:Engine Type=37;" & _
            "Jet OLEDB:Database ", _
        SQLStatement:="SELECT * FROM `Sheet1$`", _
        SQLStatement1:="", _
        SubType:=wdMergeSubTypeAccess

    With D.MailMerge
        .Destination = wdSendToNewDocument
        .SuppressBlankLines = True
        With .DataSource
            .FirstRecord = wdDefaultFirstRecord
            .LastRecord = wdDefaultLastRecord
        End With
        .Execute Pause:=False
    End With

End Sub

Find

The Find object represents the find operation. The Find object contains properties and methods to conduct a specific find operation.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim F As Word.Find
    Set F = D.Content.Find

    With F
        .Text = "Hello, World!"
        Debug.Print .Execute
        Debug.Print .Found
    End With

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim F As Word.Find
    Set F = D.Content.Find

    With F
        .Text = "Hello, World!"
        .Replacement.Text = "How's it goin'?"
        Debug.Print .Execute(Replace:=wdReplaceAll)
    End With

End Sub

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim F As Word.Find
    Set F = D.Content.Find

    With F
        .ClearHitHighlight
        .HitHighlight "Hello, World!"
    End With

End Sub

Public Sub Example()

    '''Match and highlight forms of "run"

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Dim F As Word.Find
    Set F = D.Content.Find

    With F
        .MatchAllWordForms = True
        .MatchWholeWord = True
        'Search text must be lowercase. Matches with uppercase and lowercase
        .HitHighlight "run"
    End With

End Sub

ComputeStatistics

The Document.ComputeStatistics method or the Range.ComputeStatistics method can be used to retrieve information about the content of a Document or Range. Pass a member of the WdStatistic enum to retrieve a specific value.

Public Sub Example()

    Dim D As Word.Document
    Set D = Word.Application.Documents(1)

    Debug.Print "Characters: " & D.ComputeStatistics(wdStatisticCharacters)
    Debug.Print "CharactersWithSpaces: " & D.ComputeStatistics(wdStatisticCharactersWithSpaces)
    Debug.Print "FarEastCharacters: " & D.ComputeStatistics(wdStatisticFarEastCharacters)
    Debug.Print "Lines: " & D.ComputeStatistics(wdStatisticLines)
    Debug.Print "Pages: " & D.ComputeStatistics(wdStatisticPages)
    Debug.Print "Paragraphs: " & D.ComputeStatistics(wdStatisticParagraphs)
    Debug.Print "Words: " & D.ComputeStatistics(wdStatisticWords)

End Sub